Tree Traversal

Chapter: Tree Traversal

A simple binary tree node is defined by the record structure 

(define-record btree (value left right))
where value, left and right indicate the contents and left and right children, respectively. If the empty tree is represented by '(), a binary tree can be constructed using expressions like the following: 
(define tree-1 
   (make-btree 'a 
          (make-btree 'b 
                      (make-btree 'c '() '()) 
                      (make-btree 'd '() '()))
	  (make-btree 'e 
                      (make-btree 'f '() '()) 
                      (make-btree 'g '() '()))))
representing the tree depicted below:

Let's consider writing a program called inorder to "visit" each tree node using the . A visit will be represented abstractly by the function (visit z), where z is the contents of the node being visited. A typical visit activity might be to print the value. 

(define visit
  (lambda (z)
     (display z)
     (newline)))
In deep recursive style, inorder would look like this.

(define inorder
  (lambda (tree)
     (cond [(null? tree) '()]    ; no visit to a null tree node
           [else (inorder (btree->left tree))
                 (visit (btree->value tree))
                 (inorder (btree->right tree))])))

Q. 21
Execute this program, with visit bound as shown above. What was your result?

Q. 22
How would you change this program to do preorder and postorder traversals?

Exercise 13

  1. Consider functions of 1 variable F, G and H, and let (F-k x k), (G-k x k) and (H-k x k) represent the CPS versions of F, G and H, respectively. Using the latter, show that (lambda (x y z) (begin (F x) (G y) (H z))) can be written in CPS without using any begin-like sequencing.

  2. Based on part 1, convert visit and inorder to CPS. Call them visit-k and inorder-k. Note that some continuations might use "bogus" parameters -- we'll deal with those below.

Now for something completely different...

The next exercise shows how limited a purely functional visit procedure can be in the purely functional traversal.

Exercise 14

Using tree-2 defined by 
(define tree-2
   (make-btree 20
          (make-btree 10
                      (make-btree 5 () ()) 
                      (make-btree 7 () ()))
	  (make-btree 12
                      (make-btree 6 () ()) 
                      (make-btree 8 () ()))))

  1. Can you write a visit function which, when used with inorder, computes the sum of the values at the nodes?
  2. Can you write one without side effects? Why or why not?

The last exercise illustrates how the visit to each node is isolated from the others. With a clever use of CPS we can fix this. We begin by making visit an input parameter to inorder.

Q. 23
Rewrite inorder so that visit is no longer a free variable.

Now consider the CPS version (inorder-k) that you wrote in the previous exercise. You should not find it too difficult to extend this so that visit becomes a parameter to inorder-k.

Note that in inorder-k, continuations will not have been passed any "useful" values. This is because anything useful beyond control structure takes place in visit-k, which does not return a value anyone looks at. Why not change things so that the visit-k function becomes the parameter passed to all continuations? That way, each visit function could manufacture its own successor containing any local state it might need.

Call the new procedure inorder-kv. It will begin something like this. 

(define inorder-kv
  (lambda (tree visit k)
    (cond [(null? tree) (k visit)]
	  [else (inorder-kv 
                    (btree->left tree)
                    visit
		    (lambda (new-visit) ....)
                )])))

Exercise 15

  1. Finish the definition of inorder-kv. Try executing 
    (inorder-kv tree-2 (xvisit 0) 
            (lambda (new-visit) (new-visit 'done ID)))
    where ID = (lambda (x) x) and 
    (define xvisit
  (lambda (n)
    (lambda (v k)
      (if (eq v 'done) (k n)
          (begin (printf "~a: ~a~n" n v)
                 (k (xvisit (1+ n))))))))

  2. Define yvisit so that 
    (inorder-kv tree-2 (yvisit 0) 
            (lambda (new-visit) (new-visit 'done ID)))
    produces the following output: 
    0 + 5 = 5
5 + 10 = 15
15 + 7 = 22
22 + 20 = 42
42 + 6 = 48
48 + 12 = 60
60 + 8 = 68
68

rhyspj@gwu.edu